LITE mod version creation guide

This guide describes briefly the process to create a LITE version of a pbo.

Notes:

• LITE refers to reduced quality usually.

Benefit

1. Smaller pbo size.
2. Faster game loading time.
3. Reduced GPU requirements.

The main use is for dedicated servers.

ⓘ

This cannot be used in multiplayer as a player unless the signature checking system is disabled, or the LITE version has been signed and the key is added to the server.

Scope

1. This is not an absolute beginners guide.
2. This is not about creating textures.
3. This is not about explaining tools setup.
4. This guide only handles textures. There is also sounds, scripts, mission files.

Process

Brief summary:

1. Install Arma 3 Tools
2. Install mikero's tools
3. Create a text file named CreateLITE.bat
4. Open with a text editor
5. Copy & paste the code below in it and save
6. Adjust the paths at the top and save
7. Optional: Adjust the desired texture resolution at the top and save
8. Execute the batch file

In case of error, check the created log file.

CreateLITE.bat

Show file content

rem ### Configure paths ###

set _SOURCE_PATH=x:\SourceFolder
set _TARGET_PATH=x:\TargetFolder

set _TEMP_PATH=x:\TempFolder

rem ### Configure desired texture resolution ###

set _TEXTURE_QUALITY=128

rem ### Configure tools path ###

set _MIKERO_DEPBOTOOLS=C:\Program Files (x86)\Mikero\DePboTools
set _STEAM=c:\Program Files (x86)\Steam



rem ### DONT TOUCH ###

set _MYTAG_YEAR=%date:~-4%
set _MYTAG_MONTH=%date:~-7,2%
set _MYTAG_DAY=%date:~-10,2%

rem ---

set _EXTRACTPBO_EXE=%_MIKERO_DEPBOTOOLS%\bin\ExtractPboDos.exe
set _MAKEPBO_EXE=%_MIKERO_DEPBOTOOLS%\bin\MakePbo.exe

set _PAL2PACE_EXE=%_STEAM%\SteamApps\common\Arma 3 Tools\ImageToPAA\ImageToPAA.exe

rem ----

SETLOCAL ENABLEDELAYEDEXPANSION

rem ---

@echo off
call :sub >>LITE_%_MYTAG_YEAR%_%_MYTAG_MONTH%_%_MYTAG_DAY%.log 2>&1
exit /b

rem ---

:sub

for /R %_SOURCE_PATH% %%i in (*.pbo) do (

	"%_EXTRACTPBO_EXE%" -RPK "%%i" "%_TEMP_PATH%"

	for /R "%_TEMP_PATH%" %%j in (*.paa) do (

		"%_PAL2PACE_EXE%" -size=%_TEXTURE_QUALITY% "%%j" "%%j"
	)

	for /D %%j in ("%_TEMP_PATH%\*.*") do (

		if /I not "%%j" == "%_TEMP_PATH%\TEMP" (

			if /I not "%%j" == "%_TEMP_PATH%\cache" (

				"%_MAKEPBO_EXE%" -UPDN -$ "%%j" %_TARGET_PATH%

				RD "%%j" /Q /S
			)
		)
	)
)

↑ Back to spoiler's top

Credits

• BI
• T_D
• mikero